locals {
  # If you want to use any of the variables in _this_ file, you have to load them here.
  # However, they will all be available as inputs to the module loaded in terraform.source
  # below.
  environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
  partition_vars = read_terragrunt_config(find_in_parent_folders("partition.hcl"))
  region_vars = read_terragrunt_config(find_in_parent_folders("region.hcl"))
  account_vars = read_terragrunt_config(find_in_parent_folders("account.hcl"))
  global_vars = read_terragrunt_config(find_in_parent_folders("globals.hcl"))
}

# Terragrunt will copy the Terraform configurations specified by the source parameter, along with any files in the
# working directory, into a temporary folder, and execute your Terraform commands in that folder.
terraform {
  # Double slash is intentional and required to show root of modules
  source = "git@github.xdr.accenturefederalcyber.com:mdr-engineering/xdr-terraform-modules.git//base/splunk_servers/legacy_hec?ref=v1.24.0"
}

generate "provider-legacy" {
  path      = "provider-legacy.tf"
  if_exists = "overwrite_terragrunt"
  contents  = <<EOF
provider "aws" {
  region = "us-east-1"

  assume_role {
    role_arn = "arn:aws:iam::${local.environment_vars.locals.legacy_account}:role/user/mdr_terraformer"
    session_name = "terraform-legacy"
  }

  profile = "commercial"
  alias   = "legacy"

  # Only these AWS Account IDs may be operated on by this template
  allowed_account_ids = [ ${local.environment_vars.locals.legacy_account} ]
}
EOF
}

dependency "vpc" {
  config_path = "../010-vpc-splunk"
}

dependency "indexers" {
  config_path = "../160-splunk-indexer-cluster"
}

# Include all settings from the root terragrunt.hcl file
include {
  path = find_in_parent_folders()
}

# These are the variables we have to pass in to use the module specified in the terragrunt source above
inputs = {
  # All of the inputs from the inherited hcl files are available automatically
  # (via the `inputs` section of the root `terragrunt.hcl`). However, modules
  # will be more flexible if you specify particular input values.
  tags = {
    Purpose = "Legacy ELB for Splunk Migration"
    Terraform = "aws/${basename(get_parent_terragrunt_dir())}/${path_relative_to_include()}/"
    Schedule  = "none"
  }
  prefix = local.account_vars.locals.splunk_prefix
  vpc_id = dependency.vpc.outputs.vpc_id
  vpc_cidr = local.account_vars.locals.vpc_info["vpc-splunk"]["cidr"]
  azs = dependency.vpc.outputs.azs
  public_subnets  = dependency.vpc.outputs.public_subnets
  private_subnets  = dependency.vpc.outputs.private_subnets
  elb_attachments = dependency.indexers.outputs.elb_attachments
}
