locals {
  # If you want to use any of the variables in _this_ file, you have to load them here.
  # However, they will all be available as inputs to the module loaded in terraform.source
  # below.
  environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
  partition_vars   = read_terragrunt_config(find_in_parent_folders("partition.hcl"))
  region_vars      = read_terragrunt_config(find_in_parent_folders("region.hcl"))
  account_vars     = read_terragrunt_config(find_in_parent_folders("account.hcl"))
  global_vars      = read_terragrunt_config(find_in_parent_folders("globals.hcl"))
}

# Terragrunt will copy the Terraform configurations specified by the source parameter, along with any files in the
# working directory, into a temporary folder, and execute your Terraform commands in that folder.
terraform {
  # Double slash is intentional and required to show root of modules
  source = "git@github.xdr.accenturefederalcyber.com:mdr-engineering/xdr-terraform-modules.git//base/codebuild_lcp_magic_machine?ref=v5.2.3"
}

# KMS Key
dependency "codebuild-ecr-base" {
  config_path = "../075-codebuild-ecr-base"
}

# Service Role
dependency "standard-iam" {
  config_path = "../005-standard-iam"
}

# S3 bucket dependency
dependency "xdr-binaries" {
  config_path = "../008-xdr-binaries"
}

# S3 bucket policy dependency
dependency "xdr-s3-binaries-policy" {
  config_path = "../110-xdr-binaries-write-role"
}


# VPC id dependency
dependency "codebuild-vpc" {
  config_path = "../360-codebuild-vpc"
}

#Github specific provider
generate "required_providers" {
  path      = "required_provider.tf"
  if_exists = "overwrite_terragrunt"
  contents  = <<EOF
terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "4.22.0" # 2022-07-21: Upgrade from 4.4.0; 2022-03-08: upgrade from 3.63.0
    }
    vault = {
      source  = "hashicorp/vault"
      version = "3.8.0" # 2022-07-28: upgrade from 3.4.1; 2022-04-08: upgrade from 2.19.1
    }
    sensu = {
      source  = "jtopjian/sensu"
      version = "0.12.1" # 2022-04-06: upgrade from 0.10.5
    }
    github = {
      source  = "integrations/github"
      version = "~> 4.0" # 2022-04-06: upgrade from 4.2.0
    }
  }
}
EOF
}

generate "github-provider" {
  path      = "github-provider.tf"
  if_exists = "overwrite_terragrunt"
  contents  = <<EOF
provider "github" {
  owner        = "mdr-engineering"
  base_url     = "https://github.xdr.accenturefederalcyber.com/"
}
EOF
}

# Include all settings from the root terragrunt.hcl file
include {
  path = find_in_parent_folders()
}

# These are the variables we have to pass in to use the module specified in the terragrunt source above
inputs = {
  # All of the inputs from the inherited hcl files are available automatically
  # (via the `inputs` section of the root `terragrunt.hcl`). However, modules
  # will be more flexible if you specify particular input values.
  tags = {
    Purpose   = "Build LCP OCI Image"
    Terraform = "aws/${basename(get_parent_terragrunt_dir())}/${path_relative_to_include()}/"
  }
  name                   = "oci-lcp-magic-machine"
  repository_name        = "xdr-images"
  service_role           = dependency.standard-iam.outputs.service_role
  xdr-s3-binaries-policy = dependency.xdr-s3-binaries-policy.outputs.binaries_writers_policy
  kms_key                = dependency.codebuild-ecr-base.outputs.kms_key
  vpc_id                 = dependency.codebuild-vpc.outputs.vpc_id
  public_subnets         = dependency.codebuild-vpc.outputs.public_subnets
  private_subnets        = dependency.codebuild-vpc.outputs.private_subnets
  github_clone_url       = "https://github.xdr.accenturefederalcyber.com/mdr-engineering/xdr-images"
  source_version         = "main"
  enable_webhook         = "false"
  webhook_filter_pattern = "^refs/heads/main$"
  buildspec              = "base/rhel7/oci/buildspec.yml"

}
terraform_version_constraint  = "= 1.1.6"
terragrunt_version_constraint = "= 0.36.2"