# Set common variables for the environment. This is automatically pulled in in the root terragrunt.hcl configuration to
# feed forward to the child modules.
#
# NOTE: There is only one copy of this, in the `common/` tree, and the others are symbolic links.
locals {
  aws_partition = "aws"
  aws_partition_alias = "commercial"
  common_services_account = "471284459109"
  common_profile = "${local.aws_partition == "aws-us-gov" ? "govcloud" : "commercial"}"

  # Statically setting the 'last known good' ami gives us some added flexibility
  # in building amis more regularly.
  #
  # Don't forget `lifecycle { ignore_changes = ["ami"] }` in yoru ec2
  # builds!
  amis = {
    "rhel7-base"        = "ami-0de46d7d1a164b307"
    "rhel7-master"      = "ami-0114330666839f2b9"
    "rhel7-minion"      = "ami-0425efbff72b3c702"
    "ubuntu1804-base"   = "TBD"
    "ubuntu1804-minion" = "TBD"
  }
  default_ami = local.amis["rhel7-minion"] # Allows us to easily change to a new base standard

  # If you need the raw list of all accounts, see `account_list` below
  account_map = {
    "prod" = [
      "477548533976", # Legacy MDR Prod
      "045312110490", # mdr-prod-c2
      "425831147305", # mdr-prod-modelclient
      "369723129071", # mdr-prod-malware
    ],
    "test" = [
      "527700175026", # Legacy MDR Test
      "816914342178", # mdr-test-c2
      "449047653882", # mdr-test-modelclient
      "404265901253", # mdr-test-malware
    ],
    "common" = [
      "471284459109", # mdr-common-services
    ],
  }
  # flatten the map into a single list
  account_list = flatten([
    for env, accounts in local.account_map: accounts
  ])
  # This is similar to the account_map, but used for "what accounts am I responsible for"?
  responsible_accounts = {
    "prod"   = concat(local.account_map["prod"], local.account_map["common"]),
    "test"   = local.account_map["test"],
    "common" = concat(local.account_map["prod"], local.account_map["common"], local.account_map["test"]),
  }

  aws_marketplace_ubuntu_owner_id = "679593333241"

  partition_tags = {
    aws_partition = local.aws_partition
  }
}