xdr-terraform-live/test/aws-us-gov/mdr-test-c2/096-sensu-configuration/terragrunt.hcl

locals {
  # If you want to use any of the variables in _this_ file, you have to load them here.
  # However, they will all be available as inputs to the module loaded in terraform.source
  # below.
  environment_vars = read_terragrunt_config(find_in_parent_folders("env.hcl"))
  partition_vars   = read_terragrunt_config(find_in_parent_folders("partition.hcl"))
  region_vars      = read_terragrunt_config(find_in_parent_folders("region.hcl"))
  account_vars     = read_terragrunt_config(find_in_parent_folders("account.hcl"))
  global_vars      = read_terragrunt_config(find_in_parent_folders("globals.hcl"))
}

# Terragrunt will copy the Terraform configurations specified by the source parameter, along with any files in the
# working directory, into a temporary folder, and execute your Terraform commands in that folder.
terraform {
  # Double slash is intentional and required to show root of modules
  source = "git@github.xdr.accenturefederalcyber.com:mdr-engineering/xdr-terraform-modules.git//base/sensu-configuration?ref=v4.2.7"
}

dependency "vpc-system-services" {
  config_path = "../010-vpc-system-services"
}

dependency "instance-sensu" {
  config_path = "../095-instance-sensu"
}

#Github specific provider
generate "required_providers" {
  path      = "required_provider.tf"
  if_exists = "overwrite_terragrunt"
  contents  = <<EOF
terraform {
  required_providers {
    aws = {
      source  = "hashicorp/aws"
      version = "4.4.0" # 2022-03-08: upgrade from 3.63.0; 2021-09-21: upgrade from 3.37.0
    }
    vault = {
      source  = "hashicorp/vault"
      version = "3.4.1" # 2022-04-08: upgrade from 2.19.1; 2021-04-29: upgrade from 2.18.0
    }
    sensu = {
      source  = "jtopjian/sensu"
      version = "0.12.1" # 2022-04-06: upgrade from 0.10.5
    }
    github = {
      source  = "integrations/github"
      version = "~> 4.0" # 2022-04-06: upgrade from 4.2.0
    }
  }
}
EOF
}

#Sensu specific provider
generate "sensu-provider" {
  path      = "sensu-provider.tf"
  if_exists = "overwrite_terragrunt"
  contents  = <<EOF
#Provider block for Sensu. 
provider "sensu" {
  api_url   = "https://${dependency.instance-sensu.outputs.internal_alb_address}:8080"
  username  = "admin"
  namespace = "default"
  insecure_skip_tls_verify = "true"
  #password is set with the SENSU_PASSWORD enviroment variable
}
EOF
}

# Include all settings from the root terragrunt.hcl file
include {
  path = find_in_parent_folders()
}

# These are the variables we have to pass in to use the module specified in the terragrunt source above
inputs = {
  # All of the inputs from the inherited hcl files are available automatically
  # (via the `inputs` section of the root `terragrunt.hcl`). However, modules
  # will be more flexible if you specify particular input values.
  tags = {
    Purpose   = "Sensu"
    Terraform = "aws/${basename(get_parent_terragrunt_dir())}/${path_relative_to_include()}/"
  }
  vpc_id  = dependency.vpc-system-services.outputs.vpc_id
  azs     = dependency.vpc-system-services.outputs.azs
  subnets = dependency.vpc-system-services.outputs.private_subnets
}
terraform_version_constraint  = "= 1.1.6"
terragrunt_version_constraint = "= 0.36.2"