#------------------------------------------------------------------------------
# An external ALB for the indexers for HEC
#------------------------------------------------------------------------------

#########################
# DNS Entry
module "public_dns_record_hec" {
  source = "../../../submodules/dns/public_ALIAS_record"

  name = "${var.prefix}-hec"
  target_dns_name = aws_lb.hec.dns_name
  target_zone_id  = aws_lb.hec.zone_id
  dns_info = var.dns_info

  providers = {
    aws.mdr-common-services-commercial = aws.mdr-common-services-commercial
  }
}

#########################
# Certificate
resource "aws_acm_certificate" "hec_cert" {
  domain_name       = "${var.prefix}-hec.${var.dns_info["public"]["zone"]}"
  validation_method = "DNS"

  tags = merge(var.standard_tags, var.tags)
}

resource "aws_acm_certificate_validation" "hec_cert_validation" {
  certificate_arn         = aws_acm_certificate.hec_cert.arn
  validation_record_fqdns = [for record in aws_route53_record.hec_cert_validation: record.fqdn]
}

resource "aws_route53_record" "hec_cert_validation" {
  provider = aws.mdr-common-services-commercial

  for_each = {
    for dvo in aws_acm_certificate.hec_cert.domain_validation_options : dvo.domain_name => {
      name   = dvo.resource_record_name
      record = dvo.resource_record_value
      type   = dvo.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = var.dns_info["public"]["zone_id"]
}

#########################
# ELB
resource "aws_lb" "hec" {
  tags               = merge(var.standard_tags, var.tags)
  name               = "${var.prefix}-hec"
  load_balancer_type = "application"
  security_groups    = [ aws_security_group.hec_elb_security_group.id ]
  subnets            = var.public_subnets
  internal           = false
}

resource "aws_lb_listener" "hec_443" {
  count             = local.is_moose ? 1 : 0
  load_balancer_arn = aws_lb.hec.arn
  port              = 443
  protocol          = "HTTPS"
  ssl_policy        = "ELBSecurityPolicy-TLS-1-2-2017-01"
  certificate_arn   = aws_acm_certificate.hec_cert.arn
  default_action {
    type = "forward"
    target_group_arn = aws_lb_target_group.hec_8088.arn
  }
}

resource "aws_lb_listener" "hec_8088" {
  load_balancer_arn = aws_lb.hec.arn
  port              = 8088
  protocol          = "HTTPS"
  ssl_policy        = "ELBSecurityPolicy-TLS-1-2-2017-01"
  certificate_arn   = aws_acm_certificate.hec_cert.arn
  default_action {
    type = "forward"
    target_group_arn = aws_lb_target_group.hec_8088.arn
  }
}

resource "aws_lb_target_group" "hec_8088" {
  name         = "${var.prefix}-hec-targets"
  port         = 8088
  protocol     = "HTTPS"
  target_type  = "instance"
  vpc_id       = var.vpc_id

  health_check {
    path     = "/services/collector/health/1.0"
    protocol = "HTTPS"
  }
}

# Attach the instnaces to the ELB
resource "aws_autoscaling_attachment" "hec_asg_attachments" {
  for_each = toset([ module.indexer0.asg_name[0], module.indexer1.asg_name[0], module.indexer2.asg_name[0] ])
  alb_target_group_arn = aws_lb_target_group.hec_8088.arn
  autoscaling_group_name = each.key
}
