xdr-terraform-modules/base/phantom/certificate.tf

#----------------------------------------------------------------------------
# Public DNS Certificate
#----------------------------------------------------------------------------
resource "aws_acm_certificate" "cert_private" {
  domain_name       = "phantom.${var.dns_info["private"]["zone"]}"
  validation_method = "DNS"

  lifecycle {
    create_before_destroy = true
  }

  tags = merge(var.standard_tags, var.tags)
}

resource "aws_acm_certificate_validation" "cert_private" {
  certificate_arn         = aws_acm_certificate.cert_private.arn
  validation_record_fqdns = [for record in aws_route53_record.cert_validation_private: record.fqdn]
}

resource "aws_route53_record" "cert_validation_private" {
  provider = aws.mdr-common-services-commercial

  for_each = {
    for dvo in aws_acm_certificate.cert_private.domain_validation_options : dvo.domain_name => {
      name   = dvo.resource_record_name
      record = dvo.resource_record_value
      type   = dvo.resource_record_type
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = var.dns_info["public"]["zone_id"] # private zones sitll use public dns for validation
}