xdr-terraform-modules/base/splunk_servers/alsi/elb.tf

resource "aws_lb" "alsi-alb" {
  name               = "${var.prefix}-alsi-alb"
  internal           = false
  load_balancer_type = "application"
  # Not supported for NLB
  security_groups    = [aws_security_group.alsi-alb-sg.id]
  # Note, changing subnets results in recreation of the resource
  subnets            = var.subnets
  enable_cross_zone_load_balancing = true

  access_logs {
    bucket  = "xdr-elb-${ var.environment }"
    enabled = true
  }

  tags = merge(var.standard_tags, var.tags)
}

#########################
# Listeners
resource "aws_lb_listener" "alsi-alb-listener-https" {
  load_balancer_arn = aws_lb.alsi-alb.arn
  port              = "443"
  protocol          = "HTTPS"
  ssl_policy        = "ELBSecurityPolicy-FS-1-2-Res-2019-08" # PFS, TLS1.2, most "restrictive" policy (took awhile to find that)
  certificate_arn   = aws_acm_certificate.cert.arn

  default_action {
    type             = "forward"
    target_group_arn = aws_lb_target_group.alsi-alb-target-443.arn
  }
}

# Only alb's can redirect
resource "aws_lb_listener" "alsi-alb-listener-http" {
  load_balancer_arn = aws_lb.alsi-alb.arn
  port              = "80"
  protocol          = "HTTP"

  default_action {
    type             = "redirect"

    redirect {
      port        = "443"
      protocol    = "HTTPS"
      status_code = "HTTP_301"
    }
  }
}

#########################
# Targets
resource "aws_lb_target_group" "alsi-alb-target-443" {
  name     = "${var.prefix}-alsi-alb-target-443"
  port     = 443
  protocol = "HTTPS"
  target_type = "instance"
  vpc_id   = var.vpc_id
  tags = merge(var.standard_tags, var.tags)

  health_check {
    enabled = true
    path = "/api/v1/health"
    port = 443
    protocol = "HTTPS"
  }

  # Does cribl need stickiness?
  #stickiness {
  #  type = "lb_cookie"
  #  cookie_duration = 86400 # 1 day
  #  enabled = true
  #}
}

resource "aws_lb_target_group_attachment" "alsi-alb-target-443-instance" {
  count            = var.alsi_count
  target_group_arn = aws_lb_target_group.alsi-alb-target-443.arn
  target_id        = aws_instance.instance[count.index].id
  port             = 443
}

#########################
# Security Group for ALB
resource "aws_security_group" "alsi-alb-sg" {
  name_prefix = "${var.prefix}-alsi-alb-sg"
  lifecycle { create_before_destroy = true } # handle updates gracefully
  description = "Security Group for the Cribl ALB"
  vpc_id = var.vpc_id
  tags = merge(var.standard_tags, var.tags)
}

resource "aws_security_group_rule" "alsi-alb-https-in" {
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "tcp"
  cidr_blocks       = toset(concat(var.cidr_map["vpc-access"], var.trusted_ips, var.splunk_data_sources))
  security_group_id = aws_security_group.alsi-alb-sg.id
}

resource "aws_security_group_rule" "alsi-http-in" {
  # Port 80 is open as a redirect to 443
  type              = "ingress"
  from_port         = 80
  to_port           = 80
  protocol          = "tcp"
  cidr_blocks       = toset(concat(var.cidr_map["vpc-access"], var.trusted_ips, var.splunk_data_sources))
  security_group_id = aws_security_group.alsi-alb-sg.id
}

resource "aws_security_group_rule" "alsi-alb-443-out" {
  type              = "egress"
  from_port         = 443
  to_port           = 443
  protocol          = "tcp"
  cidr_blocks       = [ var.vpc_cidr ]
  security_group_id = aws_security_group.alsi-alb-sg.id
}

#########################
# DNS Entry
resource "aws_route53_record" "alsi" {
  zone_id = var.dns_info["public"]["zone_id"]
  name    = "${ var.prefix }-alsi"
  type    = "CNAME"
  records = [aws_lb.alsi-alb.dns_name]
  ttl = "60"
  provider = aws.mdr-common-services-commercial
}