xdr-terraform-modules/base/splunk_servers/alsi/main.tf

# Some instance variables
locals {
  ami_selection = "minion" # master, minion, ...
  instance_name = "${ var.prefix }-alsi"
  is_moose = length(regexall("moose", var.prefix)) > 0 ? true : false
}

# Rather than pass in the aws security group, we just look it up.
data "aws_security_group" "typical-host" {
  name   = "typical-host"
  vpc_id = var.vpc_id
}

# Use the default EBS key
data "aws_kms_key" "ebs-key" {
  key_id = "alias/ebs_root_encrypt_decrypt"
}

resource "aws_network_interface" "instance" {
  count = var.alsi_count
  subnet_id = var.subnets[ count.index % length(var.subnets) ] # evenly distributed across subnets
  security_groups = [ data.aws_security_group.typical-host.id, aws_security_group.alsi_security_group.id ]
  description = "${local.instance_name}-${count.index}"
  tags = merge( var.standard_tags, 
                var.tags, 
                { 
                  Name = "${local.instance_name}-${count.index}", 
                  instance_num = count.index, 
                  instance_count = var.alsi_count 
                }
              )
}

resource "aws_instance" "instance" {
  count = var.alsi_count
  #availability_zone = var.azs[count.index % 2] # automatically determined by the network interface
  tenancy = "default"
  ebs_optimized = true
  disable_api_termination = var.instance_termination_protection
  instance_initiated_shutdown_behavior = "stop"
  instance_type = var.instance_type
  key_name = "msoc-build"
  monitoring = false
  iam_instance_profile = "msoc-default-instance-profile"

  ami = local.ami_map[local.ami_selection]
  # We need to ignore ebs_block_device changes, because if the AMI changes, so does the snapshot_id.
  # If they add a feature to block more specific changes (eg `ebs_block_devices[*].snapshot_id`), then
  # that could be removed.
  lifecycle { ignore_changes = [ ami, key_name, user_data, ebs_block_device ] }

  # These device definitions are optional, but added for clarity.
  root_block_device {
    volume_type = "gp2"
    #volume_size = Override via var?
    delete_on_termination = true
    encrypted = true
    kms_key_id = data.aws_kms_key.ebs-key.arn
  }

  network_interface {
    device_index = 0
    network_interface_id = aws_network_interface.instance[count.index].id
  }

  user_data = data.template_cloudinit_config.cloud-init[count.index].rendered
  tags = merge( var.standard_tags, 
                var.tags, 
                { 
                  Name = "${local.instance_name}-${count.index}", 
                  instance_num = count.index, 
                  instance_count = var.alsi_count 
                }
              )
  volume_tags = merge( var.standard_tags, 
                var.tags, 
                { 
                  Name = "${local.instance_name}-${count.index}", 
                  instance_num = count.index, 
                  instance_count = var.alsi_count 
                }
              )
}

module "private_dns_record" {
  count = var.alsi_count
  source = "../../../submodules/dns/private_A_record"

  name = "${local.instance_name}-${count.index}"
  ip_addresses = [ aws_instance.instance[count.index].private_ip ]
  dns_info = var.dns_info
  reverse_enabled = var.reverse_enabled

  providers = {
    aws.c2 = aws.c2
  }
}

data "template_file" "cloud-init" {
  count = var.alsi_count

  # Should these be in a common directory? I suspect they'd be reusable
  template = file("${path.module}/cloud-init/cloud-init.tpl")

  vars = {
    hostname = "${local.instance_name}-${count.index}"
    fqdn = "${local.instance_name}-${count.index}.${var.dns_info["private"]["zone"]}"
    splunk_prefix = var.prefix
    environment = var.environment
    salt_master  = var.salt_master
    proxy = var.proxy
    aws_partition = var.aws_partition
    aws_partition_alias = var.aws_partition_alias
    aws_region = var.aws_region
  }
}

# Render a multi-part cloud-init config making use of the part
# above, and other source files
data "template_cloudinit_config" "cloud-init" {
  count         = var.alsi_count
  gzip          = true
  base64_encode = true

  # Main cloud-config configuration file.
  part {
    filename     = "init.cfg"
    content_type = "text/cloud-config"
    content      = data.template_file.cloud-init[count.index].rendered
  }
}

## ALSI
#
# Summary:
#   Ingress:
#     443 - from ALB
#     443 - From vpc-access
#
#   Egress:
#     8089 - To Splunk
#     9997 - To Splunk
resource "aws_security_group" "alsi_security_group" {
  name_prefix = "${ var.prefix }_alsi_security_group" # name prefix and livecycle allow for smooth updates
  lifecycle { create_before_destroy = true } # handle updates gracefully
  description = "Security Group for Aggregated Log Source Ingestion"
  vpc_id = var.vpc_id
  tags = merge(var.standard_tags, var.tags)
}

# Ingress
resource "aws_security_group_rule" "alsi-alb-web-in" {
  description       = "Web access"
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "tcp"
  source_security_group_id = aws_security_group.alsi-alb-sg.id
  security_group_id = aws_security_group.alsi_security_group.id
}

resource "aws_security_group_rule" "alsi-access-web-in" {
  description       = "Web access"
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "tcp"
  cidr_blocks       = var.cidr_map["vpc-access"]
  security_group_id = aws_security_group.alsi_security_group.id
}

# Egress
resource "aws_security_group_rule" "splunk-mgmt" {
  description       = "Management Access"
  type              = "egress"
  from_port         = 8089
  to_port           = 8089
  protocol          = "tcp"
  cidr_blocks       = [ var.vpc_cidr ]
  security_group_id = aws_security_group.alsi_security_group.id
} 

resource "aws_security_group_rule" "splunk-data" {
  description       = "Management Access"
  type              = "egress"
  from_port         = 9997
  to_port           = 9998
  protocol          = "tcp"
  cidr_blocks       = [ var.vpc_cidr ]
  security_group_id = aws_security_group.alsi_security_group.id
}